我正在尝试通过 Adodb.Command 在以下查询中使用命名参数，但没有成功。

Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2) And col3 = @param1

我使用的代码是这样的。

Dim cmd
Set cmd = Server.CreateObject("Adodb.Command")
cmd.NamedParameters = True
cmd.CommandType = adCmdText
cmd.CommandText = "Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2) And col3 = @param1"
cmd.Parameters.Append cmd.CreateParameter("@param1", adVarchar, adParamInput, 20, "some text 1")
cmd.Parameters.Append cmd.CreateParameter("@param2", adVarchar, adParamInput, 20, "some text 2")
Set cmd.ActiveConnection = cn
Dim rs
Set rs = cmd.Execute

问题是，这会导致 RDBMS 端出错。

Microsoft OLE DB Provider for SQL Server error '80040e14'

Must declare the scalar variable "@param1".

如果查询是存储过程调用，则没有任何问题。所以，我想 namedparameters 仅影响调用存储过程的命令对象。
当我使用 SQL Server Profiler 跟踪查询时，我看到只运行了以下查询(请注意，没有参数声明，没有值分配)。

SQL:BatchStarting   Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2)
SQL:BatchCompleted  Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2)

但是我需要在原生 vary 查询上执行此操作。我该怎么做，没有字符串连接等的最佳做法是什么。我不想准备带问号的查询，我不喜欢按顺序传递参数(有问号且没有命名参数是必要的) ) 和多次。任何帮助将不胜感激。

误解更新:我正在寻找不依赖于数据库的通用解决方案。

最佳答案

您不能将命名参数用于 OLE DB 中的即席查询。如果您使用的是 SQL Server，您可以这样做:

Dim sql
sql = ""
sql = sql & "DECLARE @param1 varchar(20) = ?;"
sql = sql & "DECLARE @param2 varchar(20) = ?;"
sql = sql & "Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2) And col3 = @param1;"

' This section is basically the same as in the original question
Dim cmd
Set cmd = Server.CreateObject("Adodb.Command")
cmd.CommandType = adCmdText
cmd.CommandText = sql
cmd.Parameters.Append cmd.CreateParameter("@param1", adVarchar, adParamInput, 20, "some text 1")
cmd.Parameters.Append cmd.CreateParameter("@param2", adVarchar, adParamInput, 20, "some text 2")
Set cmd.ActiveConnection = cn
Dim rs
Set rs = cmd.Execute

您仍然需要按位置绑定(bind)参数，但这样一来，正确的顺序就更容易看到，并且您可以在多个位置使用相同的参数。

https://stackoverflow.com/questions/11786567/